שימוש בספק Terraform (zinn-digital/zinn)

zinn-digital/zinn הוא ספק ה-Terraform הרשמי שלנו, המפורסם ב-Terraform Registry עם גרסאות חתומות. הוא מנהל רשומות DNS בדומיינים בארגונכם, וקורא את האתרים, הדומיינים, התוכניות ואזורי האחסון שלכם כמקורות נתונים. האתרים, תיבות הדואר והתוכניות עצמם אינם מנוהלים כיום על ידי Terraform — השתמשו בלוח הבקרה, ב-API, בערכות ה-SDK או ב-Zinnector® CLI עבורם.

התקנה

terraform {
  required_providers {
    zinn = {
      source = "zinn-digital/zinn"
    }
  }
}

# api_key falls back to ZINN_API_KEY.
provider "zinn" {}

הפעל את terraform init. Terraform מוריד את הספק מהרישום ובודק את החתימה שלו.

יצירת מפתח API

פתח את הדף מפתחות API בלוח הבקרה שלך (app.zinndigital.com/api-keys) ולחץ על צור מפתח. לניהול DNS, סמן את sites.view ואת domains.dns.manage תחת הרשאות. יצא אותו לפני הפעלת Terraform:

export ZINN_API_KEY=zdk_live_…

מקורות הנתונים zinn_regions ו-zinn_plans אינם זקוקים למפתח.

ניהול רשומת DNS

data "zinn_regions" "all" {}
data "zinn_domains" "all" {}

resource "zinn_dns_record" "www" {
  domain_id = one([for d in data.zinn_domains.all.domains : d.id if d.fqdn == "example.com"])
  name      = "www"
  type      = "CNAME"
  value     = "example.com."
  ttl       = 3600
}

output "regions" { value = [for r in data.zinn_regions.all.regions : r.slug] }

הפקודה terraform apply יוצרת את הרשומה; שינוי של value או ttl מעדכן אותה במקומה; הסרת הבלוק מוחקת אותה. השדה name מקבל @ עבור ה-apex, שם יחסי כמו www, או שם מלא.

הכנסת רשומה קיימת תחת ניהול של Terraform

terraform import zinn_dns_record.www <domain_id>/<record_id>

מזהה הדומיין מגיע מ-data.zinn_domains; מזהה הרשומה מוצג על ידי רשימת רשומות ה-DNS של ה-API.

קריאת המלאי שלכם

data "zinn_sites" "all" {}
data "zinn_plans" "agency" { product_line = "agency" }

output "site_count" { value = length(data.zinn_sites.all.sites) }
output "agency_plans" { value = [for p in data.zinn_plans.agency.plans : p.code] }

הגדרות ה-Provider

• api_key — מפתח ה-API; ערך ברירת המחדל הוא ZINN_API_KEY.
• api_url — ערך ברירת המחדל הוא ZINN_API_URL, ולאחר מכן https://api.zinndigital.com.
• org — הארגון שעליו יש לפעול; ערך ברירת המחדל הוא ZINN_ORG. בדרך כלל אין בכך צורך, מאחר שמפתח שייך לארגון אחד בלבד.

לאן להמשיך מכאן

• המדריך באתר שלנו: zinndigital.com/developers/terraform
• ה-provider ב-Terraform Registry: registry.terraform.io/providers/zinn-digital/zinn
• קוד מקור: github.com/Zinn-Digital/terraform-provider-zinn