Terraform සැපයුම්කරු (zinn-digital/zinn) භාවිතය

zinn-digital/zinn යනු අත්සන් කරන ලද නිකුතු සමඟින් Terraform Registry හි ප්‍රකාශයට පත් කරන ලද අපගේ නිල Terraform සපයන්නා වේ. එය ඔබගේ සංවිධානයේ වසම් මත ඇති DNS වාර්තා කළමනාකරණය කරන අතර, දත්ත මූලාශ්‍ර ලෙස ඔබගේ අඩවි, වසම්, ප්ලෑන් සහ සත්කාරක කලාප කියවයි. අඩවි, තැපැල් පෙට්ටි සහ ප්ලෑන් Terraform මඟින් අද දින කළමනාකරණය නොකෙරේ — ඒවා සඳහා උපකරණ පුවරුව, API, SDKs හෝ Zinnector® CLI භාවිතා කරන්න.

ස්ථාපනය කරන්න

terraform {
  required_providers {
    zinn = {
      source = "zinn-digital/zinn"
    }
  }
}

# api_key falls back to ZINN_API_KEY.
provider "zinn" {}

terraform init ධාවනය කරන්න. Terraform මඟින් රෙජිස්ට්‍රියෙන් සපයන්නා බාගත කර එහි අත්සන පරීක්ෂා කරයි.

API යතුරක් සාදන්න

ඔබගේ උපකරණ පුවරුවේ API යතුරු පිටුව විවෘත කරන්න (app.zinndigital.com/api-keys) සහ යතුරක් සාදන්න ඔබන්න. DNS කළමනාකරණය සඳහා, අවසර යටතේ sites.view සහ domains.dns.manage සලකුණු කරන්න. Terraform ධාවනය කිරීමට පෙර එය අපනයනය කරන්න:

export ZINN_API_KEY=zdk_live_…

zinn_regions සහ zinn_plans දත්ත මූලාශ්‍ර සඳහා කිසිදු යතුරක් අවශ්‍ය නොවේ.

DNS වාර්තාවක් කළමනාකරණය කරන්න

data "zinn_regions" "all" {}
data "zinn_domains" "all" {}

resource "zinn_dns_record" "www" {
  domain_id = one([for d in data.zinn_domains.all.domains : d.id if d.fqdn == "example.com"])
  name      = "www"
  type      = "CNAME"
  value     = "example.com."
  ttl       = 3600
}

output "regions" { value = [for r in data.zinn_regions.all.regions : r.slug] }

terraform apply මඟින් රෙකෝඩය සාදයි; value හෝ ttl වෙනස් කිරීමෙන් එය එතැනදීම යාවත්කාලීන වේ; කොටස (block) ඉවත් කිරීමෙන් එය මැකී යයි. name සඳහා apex වෙනුවෙන් @, www වැනි සාපේක්ෂ නමක් හෝ සම්පූර්ණ නමක් පිළිගනී.

පවතින රෙකෝඩයක් Terraform යටතට ගෙන ඒම

terraform import zinn_dns_record.www <domain_id>/<record_id>

වසම් id එක data.zinn_domains වෙතින් ලබා ගන්නා අතර; වාර්තා id එක API හි DNS වාර්තා ලැයිස්තුව මඟින් පෙන්වයි.

ඔබගේ තොග විස්තර කියවන්න

data "zinn_sites" "all" {}
data "zinn_plans" "agency" { product_line = "agency" }

output "site_count" { value = length(data.zinn_sites.all.sites) }
output "agency_plans" { value = [for p in data.zinn_plans.agency.plans : p.code] }

සපයන්නාගේ සැකසුම්

• api_key — API යතුර; පෙරනිමිය ZINN_API_KEY වේ.
• api_url — පෙරනිමිය ZINN_API_URL වන අතර, ඉන්පසු https://api.zinndigital.com වේ.
• org — ක්‍රියාත්මක විය යුතු ආයතනය; පෙරනිමිය ZINN_ORG වේ. සාමාන්‍යයෙන් අනවශ්‍ය වන්නේ එක් යතුරක් එක් ආයතනයකට අයත් වන බැවිනි.

ඊළඟට යා යුතු තැන

• අපගේ වෙබ් අඩවියේ ඇති මාර්ගෝපදේශය: zinndigital.com/developers/terraform
• Terraform Registry හි ඇති සපයන්නා: registry.terraform.io/providers/zinn-digital/zinn
• මූල කේතය: github.com/Zinn-Digital/terraform-provider-zinn