ການນຳໃຊ້ຕົວໃຫ້ບໍລິການ Terraform (zinn-digital/zinn)

zinn-digital/zinn ແມ່ນ Terraform provider ຢ່າງເປັນທາງການຂອງພວກເຮົາ, ທີ່ຖືກເຜີຍແຜ່ໃນ Terraform Registry ພ້ອມກັບລຸ້ນທີ່ມີການເຊັນກຳກັບ. ມັນຈັດການ DNS records ໃນໂດເມນຕ່າງໆ ພາຍໃນອົງກອນຂອງທ່ານ, ແລະ ມັນອ່ານ ເວັບໄຊ, ໂດເມນ, ແພັກເກດ ແລະ ພາກພື້ນໂຮສຕິ້ງ ຂອງທ່ານເປັນແຫຼ່ງຂໍ້ມູນ. ເວັບໄຊ, ກ່ອງຈົດໝາຍ ແລະ ແພັກເກດຕ່າງໆ ແມ່ນຍັງບໍ່ໄດ້ຖືກຈັດການໂດຍ Terraform ໃນເວລານີ້ — ກະລຸນາໃຊ້ແຜງໜ້າປັດ, API, SDKs ຫຼື Zinnector® CLI ສຳລັບລາຍການເຫຼົ່ານັ້ນ.

ຕິດຕັ້ງ

terraform {
  required_providers {
    zinn = {
      source = "zinn-digital/zinn"
    }
  }
}

# api_key falls back to ZINN_API_KEY.
provider "zinn" {}

ເປີດໃຊ້ terraform init. Terraform ດາວໂຫຼດ provider ຈາກ registry ແລະ ກວດສອບລາຍເຊັນຂອງມັນ.

ສ້າງຄີ API

ເປີດໜ້າ ຄີ API ຂອງແຜງໜ້າປັດຂອງທ່ານ (app.zinndigital.com/api-keys) ແລ້ວກົດ ສ້າງຄີ. ສຳລັບການຈັດການ DNS, ໃຫ້ໝາຍຕິກ sites.view ແລະ domains.dns.manage ພາຍໃຕ້ ການອະນຸຍາດ. ສົ່ງອອກມັນກ່ອນທີ່ຈະເປີດໃຊ້ Terraform:

export ZINN_API_KEY=zdk_live_…

ແຫຼ່ງຂໍ້ມູນ zinn_regions ແລະ zinn_plans ບໍ່ຈໍາເປັນຕ້ອງມີຄີ.

ຈັດການບັນທຶກ DNS

data "zinn_regions" "all" {}
data "zinn_domains" "all" {}

resource "zinn_dns_record" "www" {
  domain_id = one([for d in data.zinn_domains.all.domains : d.id if d.fqdn == "example.com"])
  name      = "www"
  type      = "CNAME"
  value     = "example.com."
  ttl       = 3600
}

output "regions" { value = [for r in data.zinn_regions.all.regions : r.slug] }

terraform apply ສ້າງບັນທຶກ; ການປ່ຽນແປງ value ຫຼື ttl ຈະອັບເດດມັນຢູ່ບ່ອນເກົ່າ; ການລຶບ block ອອກຈະເປັນການລຶບມັນ. name ຮັບຮອງ @ ສຳລັບ apex, ຊື່ທີ່ກ່ຽວຂ້ອງເຊັ່ນ www, ຫຼື ຊື່ເຕັມ.

ນຳເອົາບັນທຶກທີ່ມີຢູ່ແລ້ວເຂົ້າມາຢູ່ພາຍໃຕ້ Terraform

terraform import zinn_dns_record.www <domain_id>/<record_id>

id ໂດເມນແມ່ນມາຈາກ data.zinn_domains; id ບັນທຶກແມ່ນສະແດງໂດຍລາຍການບັນທຶກ DNS ຂອງ API.

ອ່ານສິນຄ້າໃນສາງຂອງທ່ານ

data "zinn_sites" "all" {}
data "zinn_plans" "agency" { product_line = "agency" }

output "site_count" { value = length(data.zinn_sites.all.sites) }
output "agency_plans" { value = [for p in data.zinn_plans.agency.plans : p.code] }

ການຕັ້ງຄ່າຜູ້ໃຫ້ບໍລິການ

• api_key — ຄີ API; ຄ່າເລີ່ມຕົ້ນແມ່ນ ZINN_API_KEY.
• api_url — ຄ່າເລີ່ມຕົ້ນແມ່ນ ZINN_API_URL, ຈາກນັ້ນແມ່ນ https://api.zinndigital.com.
• org — ອົງກອນທີ່ຈະດຳເນີນການ; ຄ່າເລີ່ມຕົ້ນແມ່ນ ZINN_ORG. ໂດຍປົກກະຕິແລ້ວບໍ່ຈຳເປັນ, ເນື່ອງຈາກຄີໜຶ່ງຂຶ້ນກັບອົງກອນດຽວ.

ຂັ້ນຕອນຕໍ່ໄປ

• ຄູ່ມືໃນເວັບໄຊທ໌ຂອງພວກເຮົາ: zinndigital.com/developers/terraform
• ຜູ້ໃຫ້ບໍລິການໃນ Terraform Registry: registry.terraform.io/providers/zinn-digital/zinn
• ຊອດໂຄ້ດ: github.com/Zinn-Digital/terraform-provider-zinn